metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Cyberdemon
//
//===========================================================================

sound CyberSight  { prefix lump "CYBSIT" }
sound CyberActive { prefix lump "DMACT" }
sound CyberPain   { prefix lump "DMPAIN" }
sound CyberDeath  { prefix lump "CYBDTH" }
sound CyberHoof   { prefix lump "HOOF" }

thing Cyberdemon 16 native
{
    Health 4000
    Radius 40
    Height 110
    Mass 1000
    Speed 16
    PainChance 20
    MONSTER
    +NORADIUSDMG
    +HIGHERMPROB
    +RANGEHALF
    +FULLVOLSOUNDS
    +E2M8BOSS
    +E4M6BOSS
    SeeSound CyberSight
    PainSound CyberPain
    DeathSound CyberDeath
    ActiveSound CyberActive
    Obituary "%o was splattered by a cyberdemon."
    States
    {
    Spawn:
        CYBR AB 10 A_Look
        Loop
    See:
        CYBR A 3 A_Hoof
        CYBR ABBCC 3 A_Chase
        CYBR D 3 A_Metal
        CYBR D 3 A_Chase
        Loop
    Missile:
        CYBR E 6 A_FaceTarget
        CYBR F 12 A_CyberAttack
        CYBR E 12 A_FaceTarget
        CYBR F 12 A_CyberAttack
        CYBR E 12 A_FaceTarget
        CYBR F 12 A_CyberAttack
        Goto See
    Pain:
        CYBR G 10 A_Pain
        Goto See
    Death:
        CYBR H 10
        CYBR I 10 A_Scream
        CYBR JKL 10
        CYBR M 10 A_Fall
        CYBR NO 10
        CYBR P 30
        CYBR P -1 A_BossDeath
        Stop
    }
}
