metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Arch Vile
//
//===========================================================================

sound VileSight    { prefix lump "VILSIT" }
sound VileActive   { prefix lump "VILACT" }
sound VilePain     { prefix lump "VIPAIN" }
sound VileDeath    { prefix lump "VILDTH" }
sound VileRaise    { prefix lump "SLOP" }
sound VileStart    { prefix lump "VILATK" }
sound VileStop     { prefix lump "BAREXP" }
sound VileFirestrt { prefix lump "FLAMST" }
sound VileFirecrkl { prefix lump "FLAME" }

thing Archvile 64 native
{
    Health 700
    Radius 20
    Height 56
    Mass 500
    Speed 15
    PainChance 10
    MONSTER
    +SHORTMRANGE
    +DMGIGNORED
    +NOTHRESHOLD
    SeeSound VileSight
    PainSound VilePain
    DeathSound VileDeath
    ActiveSound VileActive
    //MeleeSound VileStop
    Obituary "%o was incinerated by an archvile."
    States
    {
    Spawn:
        VILE AB 10 A_Look
        Loop
    See:
        VILE AABBCCDDEEFF 2 A_VileChase
        Loop
    Missile:
        VILE G 0 BRIGHT A_VileStart
        VILE G 10 BRIGHT A_FaceTarget
        VILE H 8 BRIGHT A_VileTarget
        VILE IJKLMN 8 BRIGHT A_FaceTarget
        VILE O 8 BRIGHT A_VileAttack
        VILE P 20 BRIGHT
        Goto See
    Heal:
        VILE "[\]" 10 BRIGHT
        Goto See
    Pain:
        VILE Q 5
        VILE Q 5 A_Pain
        Goto See
    Death:
        VILE Q 7
        VILE R 7 A_Scream
        VILE S 7 A_Fall
        VILE TUVWXY 7
        VILE Z -1
        Stop
    }
}

//===========================================================================
//
// Arch Vile Fire
//
//===========================================================================

thing ArchvileFire native
{
    +NOBLOCKMAP
    +NOGRAVITY
    //RenderStyle "Add"
    States
    {
    Spawn:
        FIRE A 2 BRIGHT  A_StartFire
        FIRE BAB 2 BRIGHT  A_Fire
        FIRE C 2 BRIGHT  A_FireCrackle
        FIRE BCBCDCDCDEDED 2 BRIGHT  A_Fire
        FIRE E 2 BRIGHT  A_FireCrackle
        FIRE FEFEFGHGHGH 2 BRIGHT  A_Fire
        Stop
    }
}
