metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Imp
//
//===========================================================================

sound ImpSight  { prefix lump "BGSIT1", "BGSIT2" }
sound ImpPain   { prefix lump "POPAIN" }
sound ImpMelee  { prefix lump "CLAW" }
sound ImpDeath  { prefix lump "BGDTH1", "BGDTH2" }
sound ImpActive { prefix lump "BGACT" }
sound ImpAttack { prefix lump "FIRSHT" }
sound ImpShotx  { prefix lump "FIRXPL" }

thing DoomImp 3001 native
{
    Health 60
    Radius 20
    Height 56
    Mass 100
    Speed 8
    PainChance 200
    MONSTER
    SeeSound ImpSight
    PainSound ImpPain
    DeathSound ImpDeath
    ActiveSound ImpActive
    HitObituary "%o was slashed by an imp."
    Obituary "%o was burned by an imp."
    states
    {
    Spawn:
        TROO AB 10 A_Look
        Loop
    See:
        TROO AABBCCDD 3 A_Chase
        Loop
    Melee:
    Missile:
        TROO EF 8 A_FaceTarget
        TROO G 6 A_TroopAttack
        Goto See
    Pain:
        TROO H 2
        TROO H 2 A_Pain
        Goto See
    Death:
        TROO I 8
        TROO J 8 A_Scream
        TROO K 6
        TROO L 6 A_Fall
        TROO M -1
        Stop
    XDeath:
        TROO N 5
        TROO O 5 A_XScream
        TROO P 5
        TROO Q 5 A_Fall
        TROO RST 5
        TROO U -1
        Stop
    Raise:
        TROO MLKJI 8
        Goto See
    }
}

//===========================================================================
//
// Imp fireball
//
//===========================================================================

thing DoomImpBall native
{
    Radius 6
    Height 8
    Speed 10
    AltSpeed 20
    Damage 3
    PROJECTILE
    //RenderStyle "Add"
    SeeSound ImpAttack
    DeathSound ImpShotx
    States
    {
    Spawn:
        BAL1 AB 4 BRIGHT
        Loop
    Death:
        BAL1 CDE 6 BRIGHT
        Stop
    }
}
