metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Pain Elemental
//
//===========================================================================

sound PainSight  { prefix lump "PESIT" }
sound PainActive { prefix lump "DMACT" }
sound PainPain   { prefix lump "PEPAIN" }
sound PainDeath  { prefix lump "PEDTH" }

thing PainElemental 71 native
{
    Health 400
    Radius 31
    Height 56
    Mass 400
    Speed 8
    PainChance 128
    MONSTER
    +FLOAT
    +NOGRAVITY
    SeeSound PainSight
    PainSound PainPain
    DeathSound PainDeath
    ActiveSound PainActive
    States
    {
    Spawn:
        PAIN A 10 A_Look
        Loop
    See:
        PAIN AABBCC 3 A_Chase
        Loop
    Missile:
        PAIN D 5 A_FaceTarget
        PAIN E 5 A_FaceTarget
        PAIN F 5 BRIGHT A_FaceTarget
        PAIN F 0 BRIGHT A_PainAttack
        Goto See
    Pain:
        PAIN G 6
        PAIN G 6 A_Pain
        Goto See
    Death:
        PAIN H 8 BRIGHT
        PAIN I 8 BRIGHT A_Scream
        PAIN JK 8 BRIGHT
        PAIN L 8 BRIGHT A_PainDie
        PAIN M 8 BRIGHT
        Stop
    Raise:
        PAIN MLKJIH 8
        Goto See
    }
}
