metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Zombie man
//
//===========================================================================

sound GruntSight  { prefix lump "POSIT1", "POSIT2", "POSIT3" }
sound GruntActive { prefix lump "POSACT" }
sound GruntPain   { prefix lump "POPAIN" }
sound GruntDeath  { prefix lump "PODTH1", "PODTH2", "PODTH3" }
sound GruntAttack { prefix lump "PISTOL" }

thing ZombieMan 3004 native
{
    Health 20
    Radius 20
    Height 56
    Speed 8
    PainChance 200
    MONSTER
    SeeSound GruntSight
    AttackSound GruntAttack
    PainSound GruntPain
    DeathSound GruntDeath
    ActiveSound GruntActive
    Obituary "%o was killed by a zombieman."
    DropItem "Clip"
    States
    {
    Spawn:
        POSS AB 10 A_Look
        Loop
    See:
        POSS AABBCCDD 4 A_Chase
        Loop
    Missile:
        POSS E 10 A_FaceTarget
        POSS F 8 A_PosAttack
        POSS E 8
        Goto See
    Pain:
        POSS G 3
        POSS G 3 A_Pain
        Goto See
    Death:
        POSS H 5
        POSS I 5 A_Scream
        POSS J 5 A_Fall
        POSS K 5
        POSS L -1
        Stop
    XDeath:
        POSS M 5
        POSS N 5 A_XScream
        POSS O 5 A_Fall
        POSS PQRST 5
        POSS U -1
        Stop
    Raise:
        POSS K 5
        POSS JIH 5
        Goto See
    }
}

//===========================================================================
//
// Sergeant / Shotgun guy
//
//===========================================================================

sound ShotGuyAttack { prefix lump "SHOTGN" }

thing ShotgunGuy 3002 native
{
    Health 30
    Radius 20
    Height 56
    Mass 100
    Speed 8
    PainChance 170
    MONSTER
    SeeSound GruntSight
    PainSound GruntPain
    DeathSound GruntDeath
    ActiveSound GruntActive
    AttackSound ShotGuyAttack
    Obituary "%o was shot by a sergeant."
    DropItem "Shotgun"
    States
    {
    Spawn:
        SPOS AB 10 A_Look
        Loop
    See:
        SPOS AABBCCDD 3 A_Chase
        Loop
    Missile:
        SPOS E 10 A_FaceTarget
        SPOS F 10 bright A_SPosAttack
        SPOS E 10
        Goto See
    Pain:
        SPOS G 3
        SPOS G 3 A_Pain
        Goto See
    Death:
        SPOS H 5
        SPOS I 5 A_Scream
        SPOS J 5 A_Fall
        SPOS K 5
        SPOS L -1
        Stop
    XDeath:
        SPOS M 5
        SPOS N 5 A_XScream
        SPOS O 5 A_Fall
        SPOS PQRST 5
        SPOS U -1
        Stop
    Raise:
        SPOS L 5
        SPOS KJIH 5
        Goto See
    }
}

//===========================================================================
//
// Chaingunner
//
//===========================================================================

thing ChaingunGuy 65 native
{
    Health 70
    Radius 20
    Height 56
    Mass 100
    Speed 8
    PainChance 170
    MONSTER
    SeeSound GruntSight
    PainSound GruntPain
    DeathSound GruntDeath
    ActiveSound GruntActive
    AttackSound ShotGuyAttack
    Obituary "%o was perforated by a chaingunner."
    Dropitem "Chaingun"
    States
    {
    Spawn:
        CPOS AB 10 A_Look
        Loop
    See:
        CPOS AABBCCDD 3 A_Chase
        Loop
    Missile:
        CPOS E 10 A_FaceTarget
        CPOS FE 4 bright A_CPosAttack
        CPOS F 1 A_CPosRefire
        Goto Missile+1
    Pain:
        CPOS G 3
        CPOS G 3 A_Pain
        Goto See
    Death:
        CPOS H 5
        CPOS I 5 A_Scream
        CPOS J 5 A_Fall
        CPOS KLM 5
        CPOS N -1
        Stop
    XDeath:
        CPOS O 5
        CPOS P 5 A_XScream
        CPOS Q 5 A_Fall
        CPOS RS 5
        CPOS T -1
        Stop
    Raise:
        CPOS N 5
        CPOS MLKJIH 5
        Goto See
    }
}

//===========================================================================
//
// SS Nazi
//
//===========================================================================

sound WolfSSSight { prefix lump "SSSIT" }
sound WolfSSDeath { prefix lump "SSDTH" }

thing WolfensteinSS 84 native
{
    Health 50
    Radius 20
    Height 56
    Speed 8
    PainChance 170
    MONSTER
    SeeSound WolfSSSight
    PainSound GruntPain
    DeathSound WolfSSDeath
    ActiveSound GruntActive
    AttackSound ShotGuyAttack
    Obituary "%o met a Nazi."
    DropItem "Clip"
    States
    {
    Spawn:
        SSWV AB 10 A_Look
        Loop
    See:
        SSWV AABBCCDD 3 A_Chase
        Loop
    Missile:
        SSWV E 10 A_FaceTarget
        SSWV F 10 A_FaceTarget
        SSWV G 4 bright A_CPosAttack
        SSWV F 6 A_FaceTarget
        SSWV G 4 bright A_CPosAttack
        SSWV F 1 A_CPosRefire
        Goto Missile+1
    Pain:
        SSWV H 3
        SSWV H 3 A_Pain
        Goto See
    Death:
        SSWV I 5
        SSWV J 5 A_Scream
        SSWV K 5 A_Fall
        SSWV L 5
        SSWV M -1
        Stop
    XDeath:
        SSWV N 5
        SSWV O 5 A_XScream
        SSWV P 5 A_Fall
        SSWV QRSTU 5
        SSWV V -1
        Stop
    Raise:
        SSWV M 5
        SSWV LKJI 5
        Goto See
    }
}
