metadata { type "declarate" version "1.0.0" }

//===========================================================================
//
// Revenant
//
//===========================================================================

sound SkeletonSight  { prefix lump "SKESIT" }
sound SkeletonActive { prefix lump "SKEACT" }
sound SkeletonPain   { prefix lump "POPAIN" }
sound SkeletonMelee  { prefix lump "SKEPCH" }
sound SkeletonSwing  { prefix lump "SKESWG" }
sound SkeletonDeath  { prefix lump "SKEDTH" }
sound SkeletonAttack { prefix lump "SKEATK" }
sound SkeletonTracex { prefix lump "BAREXP" }

thing Revenant 66 native
{
    Health 300
    Radius 20
    Height 56
    Mass 500
    Speed 10
    PainChance 100
    MONSTER
    +LONGMELEE
    +RANGEHALF
    SeeSound SkeletonSight
    PainSound SkeletonPain
    DeathSound SkeletonDeath
    ActiveSound SkeletonActive
    //MeleeSound SkeletonMelee
    HitObituary "%o was punched by a revenant."
    Obituary "%o couldn't evade a revenant's fireball."
    States
    {
    Spawn:
        SKEL AB 10 A_Look
        Loop
    See:
        SKEL AABBCCDDEEFF 2 A_Chase
        Loop
    Melee:
        SKEL G 0 A_FaceTarget
        SKEL G 6 A_SkelWhoosh
        SKEL H 6 A_FaceTarget
        SKEL I 6 A_SkelFist
        Goto See
    Missile:
        SKEL J 0 BRIGHT A_FaceTarget
        SKEL J 10 BRIGHT A_FaceTarget
        SKEL K 10 A_SkelMissile
        SKEL K 10 A_FaceTarget
        Goto See
    Pain:
        SKEL L 5
        SKEL L 5 A_Pain
        Goto See
    Death:
        SKEL LM 7
        SKEL N 7 A_Scream
        SKEL O 7 A_Fall
        SKEL P 7
        SKEL Q -1
        Stop
    Raise:
        SKEL Q 5
        SKEL PONML 5
        Goto See
    }
}

//===========================================================================
//
// Revenant Tracer
//
//===========================================================================

thing RevenantTracer native
{
    Radius 11
    Height 8
    Speed 10
    Damage 10
    PROJECTILE
    SeeSound SkeletonAttack
    DeathSound SkeletonTracex
    //RenderStyle "Add"
    States
    {
    Spawn:
        FATB AB 2 BRIGHT A_Tracer
        Loop
    Death:
        FBXP A 8 BRIGHT
        FBXP B 6 BRIGHT
        FBXP C 4 BRIGHT
        Stop
    }
}

//===========================================================================
//
// Revenant Tracer Smoke
//
//===========================================================================

thing RevenantTracerSmoke native
{
    +NOBLOCKMAP
    +NOGRAVITY
    //RenderStyle "Translucent"
    States
    {
    Spawn:
        PUFF ABABC 4
        Stop
    }
}
