◆ volgrid6d_alloc()

subroutine, public volgrid6d_alloc	(	type(volgrid6d), intent(inout)	this,
		type(grid_dim), intent(in), optional	dim,
		integer, intent(in), optional	ntime,
		integer, intent(in), optional	nlevel,
		integer, intent(in), optional	ntimerange,
		integer, intent(in), optional	nvar,
		logical, intent(in), optional	ini )

Allocate the dimension descriptors of the volgrid6d object.

This method allocates the horizontal grid descriptor and the one dimensional arrays of the dimensions

time
vertical level
timerange
physical variable

This method should be explicitly used only in rare cases, it is usually called implicitly through the import interface.

Parametri

[in,out]	this	object whose decriptors should be allocated
[in]	dim	horizontal grid size X, Y
[in]	ntime	number of time levels
[in]	nlevel	number of vertical levels
[in]	ntimerange	number of different timeranges
[in]	nvar	number of physical variables
[in]	ini	if provided and .TRUE., for each allocated dimension descriptor the constructor is called without extra parameters, thus initializing everything as missing value

Definizione alla linea 408 del file volgrid6d_class.F90.

  CALL raise_fatal_error()
ENDIF
 
END SUBROUTINE volgrid6d_alloc_vol
 
 
!> Return a 2-d pointer to a x-y slice of a volume. This method works
!! both with volumes having allocated and non-allocated this%voldati
!! array, and it returns a pointer to a 2-d slice either from the
!! allocated this%voldati array or from the grid_id object on file or
!! in memory. In the second case the pointer should be either
!! ALLOCATE'd to the expected size or NULLIFY'ed, and if NULLIFY'ed,
!! it is allocated within the method, thus it will have to be
!! deallocated by the caller when not in use anymore. Since this
!! method may be called many times by a program, it is optimized for
!! speed and it does not make any check about the matching size of the
!! pointer and the array or about the allocation status of \a this, so
!! it should be called only when everything has been checked to be in
!! good shape.
SUBROUTINE volgrid_get_vol_2d(this, ilevel, itime, itimerange, ivar, voldati)
TYPE(volgrid6d),INTENT(in) :: this !< object from which the slice has to be retrieved
INTEGER,INTENT(in) :: ilevel !< index of vertical level of the slice
INTEGER,INTENT(in) :: itime !< index of time level of the slice
INTEGER,INTENT(in) :: itimerange !< index of timerange of the slice
INTEGER,INTENT(in) :: ivar !< index of physical variable of the slice
REAL,POINTER :: voldati(:,:) !< pointer to the data, if \a this%voldati is already allocated, it will just point to the requested slice, otherwise it will be allocated if and only if it is nullified on entry
 
IF (ASSOCIATED(this%voldati)) THEN
  voldati => this%voldati(:,:,ilevel,itime,itimerange,ivar)
  RETURN
ELSE
  IF (.NOT.ASSOCIATED(voldati)) THEN
    ALLOCATE(voldati(this%griddim%dim%nx,this%griddim%dim%ny))
  ENDIF
  CALL grid_id_decode_data(this%gaid(ilevel,itime,itimerange,ivar), voldati)
ENDIF
 
END SUBROUTINE volgrid_get_vol_2d
 
 
!> Return a 3-d pointer to a x-y-z slice of a volume. This method works
!! both with volumes having allocated and non-allocated this%voldati
!! array, and it returns a pointer to a 3-d slice either from the
!! allocated this%voldati array or from the grid_id object on file or
!! in memory. In the second case the pointer should be either
!! ALLOCATE'd to the expected size or NULLIFY'ed, and if NULLIFY'ed,
!! it is allocated within the method, thus it will have to be
!! deallocated by the caller when not in use anymore. Since this
!! method may be called many times by a program, it is optimized for
!! speed and it does not make any check about the matching size of the
!! pointer and the array or about the allocation status of \a this, so
!! it should be called only when everything has been checked to be in
!! good shape.
SUBROUTINE volgrid_get_vol_3d(this, itime, itimerange, ivar, voldati, zlist)
TYPE(volgrid6d),INTENT(in) :: this !< object from which the slice has to be retrieved
INTEGER,INTENT(in) :: itime !< index of time level of the slice
INTEGER,INTENT(in) :: itimerange !< index of timerange of the slice
INTEGER,INTENT(in) :: ivar !< index of physical variable of the slice
REAL,POINTER :: voldati(:,:,:) !< pointer to the data, if \a this%voldati is already allocated, it will just point to the requested slice, otherwise it will be allocated if and only if it is nullified on entry
LOGICAL,OPTIONAL,INTENT(out),ALLOCATABLE :: zlist(:) !< list of vertical level present in the data
 
INTEGER :: ilevel
LOGICAL :: done
 
IF (ASSOCIATED(this%voldati)) THEN
  voldati => this%voldati(:,:,:,itime,itimerange,ivar)
  IF (PRESENT(zlist)) zlist(:) = c_e(this%gaid(:,itime,itimerange,ivar))
  RETURN
ELSE
  IF (.NOT.ASSOCIATED(voldati)) THEN
    ALLOCATE(voldati(this%griddim%dim%nx,this%griddim%dim%ny,SIZE(this%level)))
  ENDIF
  IF (PRESENT(zlist)) THEN
    ALLOCATE(zlist(SIZE(this%level)))
  ENDIF
!$OMP PARALLEL DEFAULT(SHARED)
!$OMP MASTER
  DO ilevel = 1, SIZE(this%level)
!$OMP TASK FIRSTPRIVATE(ilevel),PRIVATE(done)
    CALL grid_id_decode_data(this%gaid(ilevel,itime,itimerange,ivar), &
     voldati(:,:,ilevel),done)
    IF (PRESENT(zlist)) zlist(ilevel) = done
!$OMP END TASK
  ENDDO
!$OMP END MASTER
!$OMP END PARALLEL
ENDIF
 
END SUBROUTINE volgrid_get_vol_3d
 
 
!> Reset a 2-d x-y slice of a volume after the data have been modified.
!! This method works both with volumes having allocated and
!! non-allocated this%voldati array, and it updates the requested
!! slice.  In case \a this%voldati is already allocated, this is a
!! no-operation while in the other case this method encodes the field
!! provided into the grid_id object on file or in memory. Since this
!! method may be called many times by a program, it is optimized for
!! speed and it does not make any check about the matching size of the
!! field and the array or about the allocation status of \a this, so